Ejemplos de consultas SPARQL

El punto de acceso SPARQL se puede consultar desde la siguiente dirección http://data.cervantesvirtual.com/openrdf-sesame/repositories/data.

Idiomas

Esta sentencia lista los idiomas más relevantes del repositorio de datos abiertos.

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX madsrdf: <http://www.loc.gov/mads/rdf/v1#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
SELECT ?language (COUNT(?manifestation) AS ?no_manifestations) ?code 
WHERE { 
	?language rdf:type madsrdf:Language .
	?language madsrdf:code ?code .
	?manifestation dc:language ?language }
GROUP BY ?language ?code

Fechas de publicación

Esta sentencia devuelve las fechas de publicación del repositorio.

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX time: <http://www.w3.org/2006/time#>
PREFIX rdam: <http://rdaregistry.info/Elements/m/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
SELECT ?lbl (COUNT(?manifestation) AS ?no_manifestations)
WHERE {
	?date rdf:type time:Instant .
	?manifestation rdam:dateOfPublication ?date . 
	?date time:inDateTime ?description .
	?description time:year ?lbl . }
GROUP BY ?lbl

Tipo de documento

Esta sentencia lista los tipos de documentos del repositorio.

PREFIX rdam: <http://rdaregistry.info/Elements/m/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
SELECT DISTINCT ?prefLabel (COUNT(?manifestation) AS ?no_manifestations)
WHERE {
	?manifestation rdam:mediaType ?mediaType .
	?mediaType skos:prefLabel ?prefLabel .
	FILTER ( lang(?prefLabel) = "en" ) }
GROUP BY ?prefLabel

Ediciones y traducciones

Esta sentencia lista las ediciones y traducciones de la obra El retablo de las maravillas disponibles en el catálogo.

PREFIX rdam: <http://rdaregistry.info/Elements/m/>
SELECT ?m ?title
WHERE {
	?m rdam:workManifested <http://data.cervantesvirtual.com/work/18605> .
	?m rdam:title ?title .
}

Publicaciones que son continuación de otras obras

Esta sentencia lista las obras que son continuación de otras obras disponibles en el repositorio.

PREFIX rdau: <http://rdaregistry.info/Elements/u/>
SELECT ?m 
WHERE {
	?m rdau:continuedBy ?m2 
}

Suplementos

Esta sentencia lista los suplementos de obras en el catálogo.

PREFIX rdau: <http://rdaregistry.info/Elements/u/>
SELECT ?m 
WHERE {
	?m rdau:supplementTo ?m2 
}

Adaptaciones

Esta sentencia lista las obras que son adaptaciones de otras en el catálogo.

PREFIX rdau: <http://rdaregistry.info/Elements/u/>
SELECT ?m 
WHERE {
	?m rdau:adaptationOf ?m2 
}